Author: tw

static void findEDT(Args _args)
{
    #AOT
    Dialog              dialog = new Dialog('Find EDT');
    SearchString        searchString;
    DialogField         dialogField = dialog.addField('SearchString');
    boolean             stopAfterFound;
    void searchNodes(boolean _extendedDataTypes)
    {
        TreeNode            treeNode;
        TreeNodeIterator    treeNodeIterator;
        SysDictType         sysDictType;
        SysDictEnum         sysDictEnum;
        Boolean             found;
        ;
        if(_extendedDataTypes)
        {
            treeNode = TreeNode::findNode(#ExtendedDataTypesPath);
        }
        else
        {
            treeNode = TreeNode::findNode(#BaseEnumsPath);
        }
        treeNodeIterator = treenode.AOTiterator();
        treeNode = treeNode.AOTfirstChild();
        treeNode = treeNodeIterator.next();
        while(treeNode)
        {
            if(treeNode.treeNodeName() like "*" + searchString + "*")
            {
                if(_extendedDataTypes)
                {
                    sysDictType = sysDictType::newTreeNode(treeNode);
                }
                if(sysDictType)
                {
                    if (sysDictType.extend()  && sysDictType.enumId())
                    {
                        info(strfmt("%1 (%2 - %3 -> %4)",treeNode.treeNodeName(), sysDictType.baseType(), extendedTypeId2name(sysDictType.extend()), enumId2Name(sysDictType.enumId()) ));
                    }
                    if(sysDictType.extend())
                    {
                        info(strfmt("%1 (%2 - %3)",treeNode.treeNodeName(), sysDictType.baseType(), extendedTypeId2name(sysDictType.extend()) ));
                    }
                    else if (sysDictType.enumId())
                    {
                        info(strfmt("%1 (%2 - %3)",treeNode.treeNodeName(), sysDictType.baseType(), enumId2Name(sysDictType.enumId()) ));
                    }
                    else
                    {
                        info(strfmt("%1 (%2)",treeNode.treeNodeName(), sysDictType.baseType()));
                    }
                }
                else
                {
                    info(strfmt("%1",treeNode.treeNodeName()));
                }
                found = true;
            }
            else if(stopAfterFound  && found)
            {
                return;
            }
            treeNode = treeNodeIterator.next();
        }
    }
    ;
    if(dialog.run())
    {
        searchString = dialogField.value();
        if(!strScan(searchString, "*", 1, 999)) //no "*"
        {
            searchString = "*" + searchString + "*";
        }
        else if(strKeep(searchString,"*") == "*"  && subStr(searchString,strLen(searchString),1)=="*") //just one final "*": beginns with
        {
            stopAfterFound = true;
        }
        info(strfmt("Find %1",searchString));
        if(searchString)
        {
            setPrefix('Extended Data Types');
            searchNodes(true);
            setPrefix('Base Enums');
            searchNodes(false);
        }
    }
}

public static boolean isLegalEntityInCountryRegion(container _isoCountryCodes, selectableDataArea _selectableDataArea = curext())
{
    #Define.DEBUG_ALL(true)                 //set true to get infolog for every country evaluated
    #Define.DEBUG_SINGLECOUNTRY(false)      //set true to get infolog when active country is evaluated
    int                             i;
    str                             callingPath;
    int                             line;

    if(#DEBUG_ALL || #DEBUG_SINGLECOUNTRY)
    {
        //initialize context
        callingPath = subStr(conPeek(xSession::xppCallStack(),3),4,999);
        line = conPeek(xSession::xppCallStack(),4);
    }

    if(#DEBUG_ALL && ! #DEBUG_SINGLECOUNTRY)
    {
        //print context of every country evaluated
        for(i=1; i <= conLen(_isoCountryCodes); i++)
        {
            info(strFmt("%1 %2 %3",conPeek(_isoCountryCodes,i),callingPath,line),"",SysInfoAction_Editor::newLineColumn(callingPath,line));
        }
    }
    if (conFind(_isoCountryCodes, SysCountryRegionCode::countryInfo(_selectableDataArea)))
    {
        if(#DEBUG_SINGLECOUNTRY)
        {
            //print context of active country evaluated
            info(strFmt("%1 %2 %3",SysCountryRegionCode::countryInfo(_selectableDataArea),callingPath,line),"",SysInfoAction_Editor::newLineColumn(callingPath,line));
        }
        return true;
    }

    return false;
}

static void deleteJob(Args _args)
{
    #define.TABLE(myTable)         //set
    #define.CONDITION(true)        //set
    #define.TRANSACTIONSIZE(100)   //set
    #TABLE #TABLE;
    int i = 1;
    ;
    while (i>0)
    {
        i=0;
        info(strfmt("%1",(select count(RecId) from #TABLE where #CONDITION).RecId));
        infolog.viewUpdate();
        ttsbegin;
        while select forupdate #TABLE where #CONDITION
        {
            #TABLE .dodelete();
            i++;
            if(i>=#TRANSACTIONSIZE)
                break;
        }
        ttscommit;
    }
}